SQL: Erstellen der Tabelle praemie

Aus DBWiki
Wechseln zu: Navigation, Suche

Zurück zur Übersicht



Mit folgendem Code in einem allgemeinen VBA-Modul lässt die Tabelle in Access anlegen:

Public Sub CreatePraemieTable()
 
   'Definition für Tabelle praemie
   Const CREATE_PRAEMIE As String = _
         "CREATE TABLE praemie (" & vbLf & _
         " ma_nr INTEGER NOT NULL," & vbLf & _
         " ausgezahlt DATE NOT NULL," & vbLf & _
         " typ INTEGER NOT NULL" & vbLf & _
         ");"
 
   'Anfügeabfrage für Tabelle praemie
   Const APP_DATA As String = _
         "INSERT INTO praemie ( ma_nr, ausgezahlt, typ )" & vbLf & _
         "VALUES ( [@ma_nr], [@ausgezahlt], [@typ] );"
 
   On Error Resume Next
   CurrentDb.Execute "DROP TABLE praemie;"
   On Error GoTo e
 
   Dim va  As Variant
   Dim v   As Variant
   Dim i   As Long
 
   BeginTrans
 
   'Tabelle anlegen
   CurrentDb.Execute CREATE_PRAEMIE, dbFailOnError
 
   va = Array(Array(7369, #3/14/2005#, 1), _
        Array(7900, #3/14/2005#, 2), _
        Array(7788, #3/14/2005#, 3))
 
   'Daten in 'praemie' schreiben
   With CurrentDb.CreateQueryDef(vbNullString, APP_DATA)
      For Each v In va
         For i = 0 To UBound(v)
            .Parameters(i) = v(i)
         Next
         .Execute dbFailOnError
      Next
   End With
 
   CommitTrans
   RefreshDatabaseWindow
   MsgBox "Tabelle 'praemie' erfolgreich mit Beispieldaten angelegt."
   Exit Sub
 
e:
   Rollback
   MsgBox "Fehler beim Anlegen der Tabelle 'praemie'."
 
End Sub



Zurück zur Übersicht